Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00030_Asynchronous Banner.ls

Text File | 2004-07-11 | 5.6 KB | 206 lines

--
-- Banner
--

-- Play a specific sound, show some text and animate while the sound is playing.
-- Requires a specific sprite grouping.
-- This banner plays asynchronously.

property ancestor


-- sound banner constants:
property bannerSprite     -- the sprite we will take over for animating
property bannerFieldCast  -- the number of the field we will be refreshing
property bannerCastList   -- the list of members we will be animating through
property delay            -- the delay between animated frames of the sound trumpet thingie
property activeHilite     -- the color of the text when it is playing.
property passiveHilite    -- the color of the text when it is not playing.


-- these are the malleable properties of the banner
property sndMember  -- the stored memberNum of the last played banner sound
property sndLib     -- the stored castLibNum of the last played banned sound
property icnPtr     -- the current frame of the sound icon animation
property lastTime   -- the last time check for the sound icon animation

global gPrinterB,gBannerartB,gLeftB,gSpeakerB,gHomeB,gHelpB,gRightB


on new me
  -- set constants:
  set bannerSprite = gSpeakerB
  set bannerFieldCast = "topBanner"
  set bannerCastList = ["speaker,1", "speaker,2", "speaker,3"]
  set delay = 7
  set activeHilite = 134
  set passiveHilite = 255

  -- initialize the ancestor:
  set ancestor = new (script "Dialog")

  -- do other initializations:
  set sndMember = 0
  set sndLib = 0
  set icnPtr = 1
  set lastTime = 0
  set the foreColor of member bannerFieldCast = passiveHilite
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end



-- set up a banner and play it, based on the member of the passed sprite.
-- depending on the command passed, we will look for sounds and text in appropriate castLibs.
-- command argument can currently be: #prompt, or #ID

on playSprite me, spr, command
  case (command) of
    #prompt:
      set sndMember = the memberNum of sprite spr
      set sndLib = the name of castLib the castLibNum of sprite spr & " prompts"

      set rootName = item 1 of (the name of member sndMember of castLib sndLib)
      setUpBanner(me, rootName)

    otherwise  -- currently #ID...or void...?
      set sndMember = the memberNum of sprite spr
      set sndLib = the name of castLib the castLibNum of sprite spr & " IDs"

      if the type of member sndMember of castLib sndLib <> #sound then return

      puppetSound 1, member sndMember of castLib sndLib
      updateStage
  end case
end



-- this looks for a sound called newRootName & ",prompt"
-- and a text member called newRootName & ",txt"
-- it puts a ref to both into the properties for this object, and then
-- loads them into the on stage members

on setupBanner me, newRootName
  if the foreColor of member bannerFieldCast = activeHilite then
    return
  end if

  -- check argument:
  if voidP (newRootName) or newRootName = "" then
    put "setUpBanner was passed an invalid argument (newRootName)."
    return 0
  end if

  -- set up the sound:
  set thisSound = (newRootName & ",prompt")
  if the number of member thisSound <= 0 then
    put thisSound && "is not a valid member (setUpBanner)."
    return 0
  end if

  set sndMember = the memberNum of member thisSound
  set sndLib = the castLibNum of member thisSound

  if the type of member sndMember of castLib sndLib <> #sound then
    put thisSound && "is not a valid #sound member (setUpBanner)."
    return 0
  end if

  -- set up the text:
  set thisText = (newRootName & ",txt")
  --  if the number of member thisText <= 0 then
  --    put thisText && "is not a valid member (setUpBanner)."
  --    return 0
  --  end if

  --  if the type of member thisText <> #field or the type of member thisText <> #text then
  --    put thisText && "is not a valid #field or #text member (setUpBanner)."
  --    return 0
  --  end if

  put the text of member thisText into field bannerFieldCast

  -- now play the banner for the first time
  -- playBanner(me)

  puppetSprite bannerSprite, TRUE

  set the foreColor of member bannerFieldCast = activeHilite

  puppetSound 1, member sndMember of castLib sndLib
  updateStage

  set icnPtr = 1
  set lastTime = the timer

  go the Frame
  return 1
end


-- this just plays back the current banner sound and text, while animating the sound icon

on playBanner me
  puppetSprite bannerSprite, TRUE

  set the foreColor of member bannerFieldCast = activeHilite

  puppetSound 1, member sndMember of castLib sndLib
  updateStage

  set icnPtr = 1
  set lastTime = the timer

  go the frame
end


-- we are done, now return stuff to normal

on endBannerSound me
  sound stop 1
  set the foreColor of member bannerFieldCast = passiveHilite
  puppetSprite bannerSprite, FALSE
  set icnPtr = 1
  set lastTime = 0
  updateStage
end


-- update the sound animation:

on stepFrame me
  stepFrame (ancestor)
  if the foreColor of member bannerFieldCast = passiveHilite then return

  if soundBusy(1) then
    if the timer >= lastTime + delay then
      set currName = getAt(bannerCastList, icnPtr)
      set the memberNum of sprite bannerSprite to the memberNum of member currName
      set the castLibNum of sprite bannerSprite to the castLibNum of member currName
      set icnPtr = icnPtr + 1
      if icnPtr > count(bannerCastList) then set icnPtr = 1
      set lastTime = the timer
    end if
    go the Frame
  else
    endBannerSound (me)
  end if
end


-- this just clears out the text for the first time you want to use it

on clearBanner me
  put " " into field bannerFieldCast
  set the foreColor of member bannerFieldCast = passiveHilite
end